Шаговый мотор 28BYJ-48 (5V) + драйвер SBT0811 (на микросхеме ULN2003) + Arduino NANO.

/*Целочисленная константа, показывающая количество фаз подачи сигналов для одного шага мотора. Для полушагового режима - 8
Для шагового - 4*/
const int OneTurnPhasesCount = 8;

/*Целочисленная константа, показывающая задержку в миллисекундах между фазами подачи сигналов мотору. Для полушагового режима - 2,
для шагового - 3*/
const int TurnPhasesDelay = 2;

/*Целочисленная константа, показывающая задержку в миллисекундах между переходами к вращению в другую сторону*/
const int Turn360Delay = 100;

/*Целочисленная константа, показывающая количество шагов, которые должен выполнить двигатель за полный оборот на 360 град.
Внутренний вал мотора совершает 64 шага за полный оборот, с учётом передаточного числа редуктора 64:1, то мотор должен совершать 64x64=4096 шагов*/
const int CountStepsOneDirection = 4096;

/*Целочисленная переменная, показывающая количество шагов, которые выполнил двигатель в одном направлении*/
int CurrentStepOneDirection = 0;

/*Целочисленная переменная, показывающая номер текущей фазы*/
int CurrentPhase = 0;

/*Целочисленная переменная, показывающая направление вращения мотора: 1 - по часовой стрелке, -1 - против*/
int TurnDirection = 1;

// Для полушагового режима

/*Массив, в котором указано какие сигналы подавать на контакты мотора в той или иной фазе. [фаза][контакт]. Контакты даются в порядке, перечисленном в массиве MotorPins - оранж., жёлт., розов., син. 0 - нет сигнала, 1 - есть сигнал*/
bool MotorTurnPhases[8][4] = {
  { 1, 0, 0, 0},
  { 1, 1, 0, 0},
  { 0, 1, 0, 0},
  { 0, 1, 1, 0},
  { 0, 0, 1, 0},
  { 0, 0, 1, 1},
  { 0, 0, 0, 1},
  { 1, 0, 0, 1} };

/*Функция CheckLastPhase проверяет не вышел ли номер текущей фазы за пределы размера массива MotorTurnPhases, который определяется переменной OneTurnPhasesCount и не пора ли поменять направление вращения*/
void CheckLastPhase()
{
  if (CurrentPhase >= OneTurnPhasesCount)
  {
    CurrentPhase = 0;
  }
  if (CurrentPhase < 0)
  {
    CurrentPhase = (OneTurnPhasesCount-1);
  }

//Увеличиваем шаг на 1
  CurrentStepOneDirection++;

//проверяем не совершил ли мотор полный оборот
  if(CurrentStepOneDirection == CountStepsOneDirection)
  {
    CurrentStepOneDirection = 0;
    TurnDirection *= -1;
    delay(Turn360Delay);
  }
}

/*Функция, в которой происходит инициализация всех переменных программы*/
void setup()
{
/*перебираем в цикле все контакты массива MotorPins и присваиваем им значение выходных, то есть дающих напряжение в 5В*/
  for (int i = 0; i < 4; i++)
    pinMode(MotorPins[i], OUTPUT);
}

/*Функция-цикл в которой задаётся поведение программы*/
void loop()
{
//проверяем индекс текущей фазы
  CheckLastPhase();

/*подаём напряжения на контакты мотора соответственно фазе, заданной в массиве MotorTurnPhases*/
  for (int i = 0; i < 4; i++)
  {
    digitalWrite(MotorPins[i], ( (MotorTurnPhases[CurrentPhase][i] == 1) ? HIGH : LOW) );
  }

//переходим к другой фазе
  CurrentPhase += TurnDirection;

// Пауза между фазами
  delay(TurnPhasesDelay);
}

/*У данного мотора 4 провода (оранж., жёлт., розов., син.), которые мы подключаем к контактам ардуино. Номера контактов указываем в массиве MotorPins, в порядке, соответствующем перечислению цветов, в нашем случае с D12 по D9*/
int MotorPins[4] = {9, 10, 11, 12};

/*Контакты от двух положений кнопки - цифровые*/
const int ButtonOn1 = 5;
const int ButtonOn2 = 4;

/*Контакт регистрирующий значение потенциометра - аналоговый*/
const int PotenciomData = 3;

/*Целочисленная константа, показывающая количество фаз подачи сигналов для одного шага мотора. Для полушагового режима - 8
Для шагового - 4*/
const int OneTurnPhasesCount = 8;

/*Целочисленная переменная, показывающая задержку в миллисекундах между фазами подачи сигналов мотору. Для полушагового режима - 2,
для шагового - 3*/
int TurnPhasesDelay = 2;

/*Целочисленная переменная, показывающая номер текущей фазы*/
int CurrentPhase = 0;

//состояние кнопки включено-выключено
int ButtonState = 0;

/*Целочисленная переменная, показывающая направление вращения мотора: 1 - по часовой стрелке, 0 - против*/
int TurnDirection = 1;

/*целочисленная константа, показывающая временную задержку между считыванием состояния кнопки и потенциометра*/
const int CheckButtonDelay = 15;

/*Целочисленная переменная показывающая, сколько прошло времени и не пора ли считывать состояние кнопки*/
int CurrentButtonDelay = 0;

//Для полушагового режима

/*Массив, в котором указано какие сигналы подавать на контакты мотора в той или иной фазе. [фаза][контакт]. Контакты даются в порядке, перечисленном в массиве MotorPins - оранж., жёлт., розов., син. 0 - нет сигнала, 1 - есть сигнал*/
bool MotorTurnPhases[8][4] = {
  { 1, 1, 0, 0},
  { 0, 1, 0, 0},
  { 0, 1, 1, 0},
  { 0, 0, 1, 0},
  { 0, 0, 1, 1},
  { 0, 0, 0, 1},
  { 1, 0, 0, 1},
  { 1, 0, 0, 0} };

/*Функция, в которой происходит инициализация всех переменных программы*/
void setup()
{
/*перебираем в цикле все контакты массива MotorPins и присваиваем им значение выходных, то есть дающих напряжение в 5В*/
  for (int i = 0; i < 4; i++)
    pinMode(MotorPins[i], OUTPUT);

  pinMode(ButtonOn1, INPUT);
  pinMode(ButtonOn2, INPUT);
  pinMode(PotenciomData, INPUT);
}

/*Функция-цикл в которой задаётся поведение программы*/
void loop()
{
  if(CurrentButtonDelay >= CheckButtonDelay)
  {
    CheckButtonState();
    CurrentButtonDelay = 0;
  }

  if(ButtonState != 0)
  {
//проверяем индекс текущей фазы
    CheckLastPhase();

/*подаём напряжения на контакты мотора соответственно фазе, заданной в массиве MotorTurnPhases*/
    for (int i = 0; i < 4; i++)
    {
      digitalWrite(MotorPins[i], ( (MotorTurnPhases[CurrentPhase][i] == 1) ? HIGH : LOW) );
    }

//переходим к другой фазе
    CurrentPhase += TurnDirection;

// Пауза между фазами
    delay(TurnPhasesDelay);
  }

  CurrentButtonDelay += TurnPhasesDelay;
}

/*Функция CheckLastPhase проверяет не вышел ли номер текущей фазы за пределы размера массива MotorTurnPhases, который определяется переменной OneTurnPhasesCount*/
void CheckLastPhase()
{
  if (CurrentPhase >= OneTurnPhasesCount)
  {
    CurrentPhase = 0;
  }
  if (CurrentPhase < 0)
  {
    CurrentPhase = (OneTurnPhasesCount-1);
  }
}

/*функция, в которой проверяется текущее состояние кнопки*/
void CheckButtonState()
{
  int CurrentButtonState = 0, CurrentButtonDirection = 0, CurrentTurnPhasesDelay = 0;

//считываем данные с положения кнопки I
  bool readbuttonparam = digitalRead(ButtonOn1);

  if(readbuttonparam)
  {
    CurrentButtonState = 1;
    CurrentButtonDirection = 1;
  }

//считываем данные с положения кнопки II
  readbuttonparam = digitalRead(ButtonOn2);

  if(readbuttonparam)
  {
    CurrentButtonState = 1;
    CurrentButtonDirection = -1;
  }

/*Проверяем, изменилось ли состояние кнопки по сравнению с предыдущим, и если изменилось, то записываем изменения в глобальные переменные*/
  if(ButtonState != CurrentButtonState)
  {
    ButtonState = CurrentButtonState;
  }

  if(TurnDirection != CurrentButtonDirection)
  {
    TurnDirection = CurrentButtonDirection;
  }

  CurrentTurnPhasesDelay = map(analogRead(PotenciomData), 0, 1023, 2, CheckButtonDelay);

  if(TurnPhasesDelay != CurrentTurnPhasesDelay)
  {
    TurnPhasesDelay = CurrentTurnPhasesDelay;
  }
}